languages/latex: add latex support wiht lsp, formatter and highlighting

configuration.nix

@@ -103,6 +103,7 @@ isMaximal: {
       tera.enable = false;
       twig.enable = false;
       fluent.enable = false;
+      latex.enable = false;
 
       # Nim LSP is broken on Darwin and therefore
       # should be disabled by default. Users may still enable

docs/manual/release-notes/rl-0.9.md

@@ -262,6 +262,9 @@
   [twig-cs-fixer](https://github.com/VincentLanglet/Twig-CS-Fixer) aren't
   packaged for nix.
 
+- Added `languages.latex`. Currently only highlighting, formatting and lsp. No
+  previewing yet.
+
 - Didn't Add
   [`syntax-gaslighting`](https://github.com/NotAShelf/syntax-gaslighting.nvim),
   you're crazy.

modules/plugins/languages/default.nix

@@ -31,6 +31,7 @@ in {
     ./json.nix
     ./lua.nix
     ./markdown.nix
+    ./latex.nix
     ./nim.nix
     ./vala.nix
     ./nix.nix

modules/plugins/languages/latex.nix

@@ -0,0 +1,111 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.options) literalExpression mkEnableOption mkOption;
+  inherit (lib.types) bool enum listOf;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.latex;
+  defaultServers = ["texlab"];
+  servers = {
+    texlab = {
+      enable = true;
+      cmd = [(getExe pkgs.texlab) "run"];
+      filetypes = ["plaintex" "tex"];
+      root_markers = [".git"];
+    };
+  };
+
+  defaultFormat = ["tex-fmt"];
+  formats = {
+    tex-fmt = {
+      command = getExe pkgs.tex-fmt;
+    };
+  };
+in {
+  options.vim.languages.latex = {
+    enable = mkEnableOption "LaTeX language support";
+
+    treesitter = {
+      enable = mkOption {
+        type = bool;
+        default = config.vim.languages.enableTreesitter;
+        defaultText = literalExpression "config.vim.languages.enableTreesitter";
+        description = "Enable LaTeX treesitter";
+      };
+      latexPackage = mkGrammarOption pkgs "latex";
+      bibtexPackage = mkGrammarOption pkgs "bibtex";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "LaTeX LSP support"
+        // {
+          default = config.vim.lsp.enable;
+          defaultText = literalExpression "config.vim.lsp.enable";
+        };
+
+      servers = mkOption {
+        description = "LaTeX LSP server to use";
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+      };
+    };
+
+    format = {
+      enable =
+        mkEnableOption "LaTeX formatting"
+        // {
+          default = config.vim.languages.enableFormat;
+          defaultText = literalExpression "config.vim.languages.enableFormat";
+        };
+
+      type = mkOption {
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+        description = "LaTeX formatter to use";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [
+        cfg.treesitter.latexPackage
+        cfg.treesitter.bibtexPackage
+      ];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.tex = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+  ]);
+}