languages/fish: init

configuration.nix

@@ -113,6 +113,7 @@ isMaximal: {
       gettext.enable = false;
       fluent.enable = false;
       jq.enable = false;
+      fish.enable = false;
 
       # Nim LSP is broken on Darwin and therefore
       # should be disabled by default. Users may still enable

docs/manual/release-notes/rl-0.9.md

@@ -479,11 +479,17 @@ https://github.com/gorbit99/codewindow.nvim
 [neocmakelsp]: https://github.com/neocmakelsp/neocmakelsp
 [arduino-language-server]: https://github.com/arduino/arduino-language-server
 [glsl_analyzer]: https://github.com/nolanderc/glsl_analyzer
+[fish-lsp]: https://www.fish-lsp.dev/
+[fish_indent]: https://fishshell.com/docs/current/cmds/fish_indent.html
 
 - Add CMake support with [neocmakelsp].
 - Add Arduino support with [arduino-language-server].
 - Add GLSL support with [glsl_analyzer].
 - Update fidget-nvim setupOpts and fix NvimTree issue.
+- Add Fish support via {option}`vim.languages.fish.enable` using [fish-lsp] and
+  [fish_indent]. Most of the work done by
+  [poseidon-rises](https://github.com/poseidon-rises) in
+  [!1107](https://github.com/NotAShelf/nvf/pull/1107).
 
 [itscrystalline](https://github.com/itscrystalline):
 

modules/plugins/languages/default.nix

@@ -16,6 +16,7 @@ in {
     ./scss.nix
     ./elixir.nix
     ./elm.nix
+    ./fish.nix
     ./fsharp.nix
     ./gleam.nix
     ./glsl.nix

modules/plugins/languages/fish.nix

@@ -0,0 +1,102 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkOption mkEnableOption literalExpression;
+  inherit (lib.meta) getExe';
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum bool listOf;
+  inherit (lib) genAttrs;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.fish;
+
+  defaultServers = ["fish-lsp"];
+  servers = ["fish-lsp"];
+
+  defaultFormat = ["fish_indent"];
+  formats = {
+    fish_indent = {
+      command = getExe' pkgs.fish "fish_indent";
+    };
+  };
+in {
+  options.vim.languages.fish = {
+    enable = mkEnableOption "Fish language support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "Fish treesitter"
+        // {
+          default = config.vim.languages.enableTreesitter;
+          defaultText = literalExpression "config.vim.languages.enableTreesitter";
+        };
+      package = mkGrammarOption pkgs "fish";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "Fish LSP support"
+        // {
+          default = config.vim.lsp.enable;
+          defaultText = literalExpression "config.vim.lsp.enable";
+        };
+      servers = mkOption {
+        type = listOf (enum servers);
+        default = defaultServers;
+        description = "Fish LSP server to use";
+      };
+    };
+
+    format = {
+      enable = mkOption {
+        type = bool;
+        default = config.vim.languages.enableFormat;
+        defaultText = literalExpression "config.vim.languages.enableFormat";
+        description = "Enable Fish formatting";
+      };
+      type = mkOption {
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+        description = "Fish formatter to use";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp = {
+        presets = genAttrs cfg.lsp.servers (_: {enable = true;});
+        servers = genAttrs cfg.lsp.servers (_: {
+          filetypes = ["fish"];
+        });
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.fish = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+  ]);
+}

modules/plugins/lsp/presets/default.nix

@@ -17,6 +17,7 @@
     ./elixir-ls.nix
     ./elm-language-server.nix
     ./emmet-ls.nix
+    ./fish-lsp.nix
     ./fsautocomplete.nix
     ./gleam.nix
     ./glsl_analyzer.nix

modules/plugins/lsp/presets/fish-lsp.nix

@@ -0,0 +1,24 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.types) mkLspPresetEnableOption;
+
+  cfg = config.vim.lsp.presets.fish-lsp;
+in {
+  options.vim.lsp.presets.fish-lsp = {
+    enable = mkLspPresetEnableOption "fish-lsp" "Fish" [];
+  };
+
+  config = mkIf cfg.enable {
+    vim.lsp.servers.fish-lsp = {
+      enable = true;
+      cmd = [(getExe pkgs.fish-lsp) "start"];
+      root_markers = ["config.fish" ".git"];
+    };
+  };
+}