diff --git a/configuration.nix b/configuration.nix
index 8b308036..e09d4589 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -112,6 +112,7 @@ isMaximal: {
       gettext.enable = false;
       fluent.enable = false;
       jq.enable = false;
+      standard-ml.enable = false;
 
       # Nim LSP is broken on Darwin and therefore
       # should be disabled by default. Users may still enable
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index ffdccb8e..1c80a353 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -393,6 +393,8 @@
 - Added [`biomejs`](https://biomejs.dev/) as extra diagnostics provider to
   `languages.ts`.
 
+- Added `languages.standard-ml`.
+
 - Added `languages.vue`.
 
 - Add `languages.fluent` using the official plugin. This only provides
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 368287a7..2e493f27 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -13,6 +13,7 @@ in {
     ./clojure.nix
     ./cmake.nix
     ./css.nix
+    ./standard-ml.nix
     ./scss.nix
     ./elixir.nix
     ./elm.nix
diff --git a/modules/plugins/languages/standard-ml.nix b/modules/plugins/languages/standard-ml.nix
new file mode 100644
index 00000000..ec97f00e
--- /dev/null
+++ b/modules/plugins/languages/standard-ml.nix
@@ -0,0 +1,115 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) literalExpression mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.meta) getExe;
+  inherit (lib) genAttrs;
+  inherit (lib.types) enum listOf;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.generators) mkLuaInline;
+
+  cfg = config.vim.languages.standard-ml;
+
+  defaultServers = ["millet"];
+  servers = ["millet"];
+
+  defaultFormat = ["smlfmt"];
+  formats = {
+    smlfmt = {
+      command = getExe pkgs.smlfmt;
+      stdin = false;
+      args = mkLuaInline ''
+        function(self, ctx)
+          return {
+            "--force",
+            "-tab-width", ctx.shiftwidth,
+            "-indent-width", ctx.shiftwidth,
+            "$FILENAME",
+          }
+        end
+      '';
+    };
+  };
+in {
+  options.vim.languages.standard-ml = {
+    enable = mkEnableOption "Standard ML support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "Standard ML treesitter"
+        // {
+          default = config.vim.languages.enableTreesitter;
+          defaultText = literalExpression "config.vim.languages.enableTreesitter";
+        };
+      package = mkGrammarOption pkgs "sml";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "Standard ML LSP support"
+        // {
+          default = config.vim.lsp.enable;
+          defaultText = literalExpression "config.vim.lsp.enable";
+        };
+      servers = mkOption {
+        type = listOf (enum servers);
+        default = defaultServers;
+        description = "Standard ML LSP server to use";
+      };
+    };
+
+    format = {
+      enable =
+        mkEnableOption "Standard ML formatting"
+        // {
+          default = config.vim.languages.enableFormat;
+          defaultText = literalExpression "config.vim.languages.enableFormat";
+        };
+
+      type = mkOption {
+        description = "Standard ML formatter to use";
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp = {
+        presets = genAttrs cfg.lsp.servers (_: {enable = true;});
+        servers = genAttrs cfg.lsp.servers (_: {
+          filetypes = ["sml"];
+        });
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.sml = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+  ]);
+}
diff --git a/modules/plugins/lsp/presets/default.nix b/modules/plugins/lsp/presets/default.nix
index f5f71c35..db5fc322 100644
--- a/modules/plugins/lsp/presets/default.nix
+++ b/modules/plugins/lsp/presets/default.nix
@@ -33,6 +33,7 @@
     ./lua-language-server.nix
     ./markdown-oxide.nix
     ./marksman.nix
+    ./millet.nix
     ./neocmakelsp.nix
     ./nil.nix
     ./nimlsp.nix
diff --git a/modules/plugins/lsp/presets/millet.nix b/modules/plugins/lsp/presets/millet.nix
new file mode 100644
index 00000000..e63d5267
--- /dev/null
+++ b/modules/plugins/lsp/presets/millet.nix
@@ -0,0 +1,24 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.types) mkLspPresetEnableOption;
+
+  cfg = config.vim.lsp.presets.millet;
+in {
+  options.vim.lsp.presets.millet = {
+    enable = mkLspPresetEnableOption "millet" "Millet Standard ML" [];
+  };
+
+  config = mkIf cfg.enable {
+    vim.lsp.servers.millet = {
+      enable = true;
+      cmd = [(getExe pkgs.millet)];
+      root_markers = [".git" "millet.toml"];
+    };
+  };
+}